ASP中class Property Get、Property Let 的簡單介紹和使用方法

2011/7/8 11:14:02  出處：本站   人氣：108次    字號：小  中  大

本文將給大家一起分享介紹到的是關于ASP中class Property Get、Property Let 的簡單介紹和使用方法，希望對大家有所幫助。

<%
'在 Class 塊中，成員通過相應的聲明語句被聲明為 Private(私有成員，只能在類內部調用) 或 Public(公有成員，可以在類內外部調用) 。
'被聲明為 Private 的將只在 Class 塊內是可見的。被聲明為 Public 不僅在 Class 塊的內部是可見的，對 Class 塊之外的代碼也是可見的。
'沒有使用 Private 或 Public 明確聲明的被默認為 Public。在類的塊內部被聲明為 Public 的過程（Sub 或 Function）將成為類的方法。
'Public 變量將成為類的屬性，同使用 Property Get、Property Let 和 Property Set 顯式聲明的屬性一樣。
'類的缺省屬性和方法是在它們的聲明部分用 Default 關鍵字指定的。
Class myClass
'//----聲明（聲明就是定義）myclass類的類內部（私有的[Private]）變量
Private strAuthor
Private strVersion
Private strExample

'//---------------------------定義類的事件-------------------------------//
'//----Class_Initialize()是類的初始化事件，只要一開始使用該類，首先會觸發該部分的執行.
'下面我們會在該成員中初始化該類的作者和版本以在屏幕上顯示一下該類已經開始了

Private Sub Class_Initialize()
strAuthor = "思源"
strVersion = "1.0"
Response.Write "<br/>myClass開始了<br/>"
End Sub
'//----Class_Terminate()是類的結束事件，只要一退出該類，就會觸發該事件.
'下面我們會該事件中設定退出該類時會在屏幕上顯示該類已結束了。

Private Sub Class_Terminate()
Response.Write "<br/>myClass結束了<br/>"
End Sub

'//---------------------------用戶自己定義的方法-------------------------------//

'//----該方法返回一個版本信息

Public Sub Information()
Response.Write "<br/>Coding By <a href='mailto:coder@sinobe.com'>Maxid_Zen</a> @ <a href='http://www.design60s.com'>www.design60s.com</a>.<br/>"
End Sub

'//---------------------------定義類的輸出屬性-------------------------------//

'//----定類的屬性，該屬性是讓用戶初始化strExample變量

Public Property Let setExample(ByVal strVar)
strExample = strVar
End Property

'//---------------------------定義類的輸出屬性-------------------------------//

'//----定義類的屬性，該屬性是返回一個版本號

Public Property Get Version
Version = strVersion
End Property

'//----定義類的屬性，該屬性是返回該類的作者號

Public Property Get Author
Author = strAuthor
End Property

'//----定義類的屬性，該屬性是返回用戶自定義信息

Public Property Get Example
Example = strExample
End Property


End Class
%>
<%

'//-------這里是使用該類的例子

Dim oneNewClass

Set oneNewClass = new myClass

Response.Write "作者：" & oneNewClass.Author & "<br/>"
Response.Write "版本：" & oneNewClass.Version & "<br/>"

oneNewClass.setExample = "這是一個簡單類的例子"

Response.Write "用戶自定義：" & oneNewClass.Example & "<br/>"

oneNewClass.Information

Set oneNewClass = Nothing

%>

Property Get 語句
在 Class 塊中，聲明構成用來取得（返回）的值的屬性過程的主體的名稱、參數和代碼。

[Public [Default]| Private] Property Get name [(arglist)]
[statements]
[[Set] name = expression]
[Exit Property]
[statements]
[[Set] name = expression]
End Property

參數
Public

表明Property Get 過程可以被所有腳本中的其他過程訪問。

Default

只與 Public 關鍵字一起使用，表明 Property Get 過程中定義的屬性為類的缺省屬性。

Private

表明 Property Get 過程只對定義它的 Class 塊中的其他過程是可以訪問的。

name

Property Get 過程的名稱；遵守標準的變量命名規則，區別僅僅在于它可以與同一Class塊中的Property Let 或 Property Set過程。

arglist

該變量列表代表了 Property Get 過程被調用時傳遞給它的參數。多個參數之間用逗號分隔開。Property Get 過程中的每個參數的名稱必須與 Property Let 過程中的相應參數相同(如果有的話)。

statements

任意的一組語句，將在 Property Get 過程的主體中執行。

Set

在將對象作為 Property Get 過程的返回值時使用的關鍵字。

expression

Property Get 過程的返回值。

說明
如果未使用 Public 或 Private明確聲明，則 Property Get 過程被缺省為公有的，即它們對于腳本中的其他所有過程都是可見的。Property Get過程中的局部變量的值在不同的過程調用之間是不保存的。

在其他任何過程(例如 Function 或 Property Let) 內部都不能定義 Property Get 過程。

Exit Property 語句將導致立即從 Property Get 過程中退出。程序將繼續執行調用 Property Get 過程的語句之后的程序。Exit Property 語句可以出現在 Property Get 過程中的任何位置，次數不限。

與Sub 和 Property Let 過程類似，Property Get 過程是能夠接受參數的過程，可以執行一系列的語句，以及改變參數的值。然而，與Sub 和 Property Let 不同的是，Property Get 過程可以被用于表達式的右側，用與使用Function 或屬性名稱相同的方式來返回屬性的值。

Property Let 語句
在 Class 塊中，聲明名稱、參數和代碼等，它們構成了賦值（設置）的 Property 過程的主體。

[Public | Private] Property Let name (
[arglist,] value
)
[statement]
[Exit Property]
[statement]
End Property

參數
Public

表明 Property Let 過程可以被所有腳本中的其他所有過程訪問。

Private

表明 Property Let 過程只能被定義之的 Class 塊內的其他過程訪問。

name

Property Let 過程的名稱；遵守標準的變量命名規則，區別僅僅在于其名稱可以與相同 Class 塊中的 Property Get 或 Property Set 過程相同。

arglist

該變量列表代表了在調用時被傳遞到 Property Let 過程的參數。多個參數之間用逗號隔開。Property Let 過程的每個參數的名字必須與 Property Get 過程中的相應參數相同。此外， Property Let 過程的參數比相應的 Property Get 過程總要多一個。該參數為被賦予屬性的值。

value

該變量中包含要賦予屬性的值。當過程被調用時，該參數將出現在調用表達式的右側。

statement

任意的一組語句，將在 Property Let 過程的主體內執行。

注意每個 Property Let 語句必須為所定義的屬性定義至少一個參數。該參數（在存在多個參數時的最后一個參數）包含了當 Property Let 語句被調用時要賦予屬性的值。該參數在前面的語法中被稱為value。

說明
如果未明確地使用 Public 或 Private進行指定，Property Let 過程被缺省設置為公有的，即它們對于腳本內的其他所有過程都是可見的。Property Let過程中的局部變量的值在不同的過程調用之間是不被保存的。

在其他任何過程（例如 Function 或 Property Get）的內部不能夠定義 Property Let 過程。

Exit Property 語句將導致立即從 Property Let 過程中退出。程序將從調用 Property Let 過程的語句之后的點繼續執行。Exit Property 語句可以出現在 Property Let 過程中的任何位置，次數不限。

與 Function 和 Property Get 過程類似，Property Let 過程是一個單獨的過程，它可以接受參數，執行一系列的語句，還可以改變參數的值。不過，與Function 和 Property Get 過程不同的是，它們兩者都返回一個值，而Property Let過程只能用于屬性賦值表達式的左側。

Property Set 語句
在 Class 塊中，聲明名稱、參數和代碼，這些構成了將引用設置到對象的 Property 過程的主體。

[Public | Private] Property Set name(
[arglist,] reference
)
[statement]
[Exit Property]
[statement]
End Property

參數
Public

表明 Property Set 過程可以被所有腳本中的其他所有過程訪問。

Private

表明 Property Set 過程只能被聲明之的同一 Class 塊中的其他過程訪問。

name

Property Set 過程的名稱；遵守標準的變量命名規則，不過該名稱可以與同一個 Class 塊中的 Property Get 或 Property Let 過程相同。

arglist

變量列表，代表在 Property Set 過程被調用時傳遞給它的參數。多個參數之間用逗號分隔開。此外，Property Set 過程將總是比它相應的 Property Get 過程多一個參數。這個多出來的參數是被賦予的對象。

reference

變量，其中包含被用于對象引用賦值的右側的對象引用。

statement

將要在 Property Set 過程主體中執行的任何一組語句。

注意每個 Property Set 語句都必須為所定義的過程定義至少一個參數。當 Property Set 語句所定義的過程被調用時，該必需參數（在多個參數時為最后一個參數）中將為屬性提供實際的對象引用。在前面的語法中，該參數被稱為引用。

說明
除非使用 Public 或 Private 明確地進行指定，否則 Property Set 過程被設置為缺省的公有模式，即腳本中的其他所有過程都是可見的。在不同的過程調用時，Property Set 過程中的局部變量是不保存的。

在其他任何過程（例如Function或Property Let）中都不能夠定義Property Set過程。

Exit Property 語句將導致立即從 Property Set 過程中退出。程序將繼續執行調用 Property Set 過程之后的語句。Exit Property 語句的數量不受限制，可以出現在 Property Set 過程中的任何位置。

與 Function 和 Property Get 過程類似，Property Set 過程是一個單獨的過程，它可以有若干參數，執行一系列的語句，還可以改變參數的值。然而，與 Function 和 Property Get 過程不同的是，函數和過程都可以返回值，而 Property Set 過程對象引用賦值（Set 語句）的左側。